【API Function】

[使用しているCPUの取得]

　使用しているCPUの取得には、GetSystemInfo関数を使用します。
この関数は、引数にSYSTEM_INFO構造体を持ち、使用しているCPU情報は、この中のdwProcessorTypeに格納されます。この関数に戻り値はありません。

(GetSystemInfo関数の使用方法)
このサンプルでは、CommandButtonをクリックすることでCPU情報をメッセージボックスに表示します。
フォームのGeneralセクションに次の宣言コードを追加して下さい。

'構造体の定義
Private Type SYSTEM_INFO
    dwOemID As Long
    dwPageSize As Long
    lpMinimumApplicationAddress As Long
    lpMaximumApplicationAddress As Long
    dwActiveProcessorMask As Long
    dwNumberOrfProcessors As Long
    dwProcessorType As Long　　　　　'使用しているCPU情報
    dwAllocationGranularity As Long
    dwReserved As Long
End Type

'APIの宣言
Private Declare Sub GetSystemInfo Lib "kernel32" (lpSystemInfo _
                As SYSTEM_INFO)

    'CPU名の定義
    Private Const PROCESSOR_INTEL_386 = 386&
    Private Const PROCESSOR_INTEL_486 = 486&
    Private Const PROCESSOR_INTEL_PENTIUM = 586&
    Private Const PROCESSOR_MIPS_R4000 = 4000&
    Private Const PROCESSOR_ALPHA_21064 = 21064&

次に、フォームにCommandButtonを配置し、次のコードを追加します。

Private Sub Command1_Click()
    Dim SysInfo As SYSTEM_INFO
    Dim ProType As String 'プロセッサー名
    Dim msg As String

    Call GetSystemInfo(SysInfo)

    Select Case SysInfo.dwProcessorType
        Case PROCESSOR_INTEL_386
            ProType = "Intel386"
        Case PROCESSOR_INTEL_486
            ProType = "Intel486"
        Case PROCESSOR_INTEL_PENTIUM
            ProType = "Intel Pentium"
        Case PROCESSOR_MIPS_R4000
            ProType = "MIPS R4000"
        Case PROCESSOR_ALPHA_21064
            ProType = "ALPHA 21064"
    End Select
    msg = "使用CPU : " & ProType
    MsgBox msg, vbInformation + vbOKOnly, "使用CPU情報"
End Sub

API Functionインデックストップ